Arduino Nano - Configuratie uitlezen vanaf SD-kaart
Deze tutorial legt uit hoe u een configbestand kunt gebruiken op een Micro SD-kaart. We behandelen specifiek:
- Hoe u een config.txt-bestand aanmaakt op een Micro SD-kaart, met key-value paren
- Hoe u de config leest vanaf de Micro SD-kaart en opslaat in een int variabele
- Hoe u de config leest vanaf de Micro SD-kaart en opslaat in een float variabele
- Hoe u de config leest vanaf de Micro SD-kaart en opslaat in een String variabele
Hardware Vereist
Of u kunt de volgende kits kopen:
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Over de Micro SD Kaart Module
Als u niet bekend bent met de Micro SD-kaartmodule, inclusief de pinout, werking en programmeren, bekijk dan de Arduino Nano - Micro SD Card tutorial.
Hoe Het Werkt
Elke key-value paar wordt op de Micro SD-kaart op een aparte regel opgeslagen. De key en value worden gescheiden door een = teken. Elke key-value paar wordt door een nieuwe regel van elkaar gescheiden.
De Arduino Nano code zoekt de key op en vindt de bijbehorende value, die wordt opgeslagen in een variabele. De variabele kan het type int, float of String zijn.
Bedradingsschema
- U kunt mannelijke naar vrouwelijke jumperdraden gebruiken om de Micro SD-kaartmodule met de Arduino Nano te verbinden
Deze afbeelding is gemaakt met Fritzing. Klik om de afbeelding te vergroten.
- Of u kunt de Micro SD-kaartmodule op een breadboard (experimenteerprint) plaatsen en vervolgens mannelijke naar mannelijke jumperdraden gebruiken
Deze afbeelding is gemaakt met Fritzing. Klik om de afbeelding te vergroten.
Hoe config uitlezen naar variabelen
- Maak een config.txt bestand aan op uw PC met Notepad of Notepad++.
- Kopieer de volgende key-value paren en plak ze in het config.txt bestand:
myString_1=Hello
myString_2=ArduinoGetStarted.com
myInt_1=2
myInt_2=-105
myFloat_1=0.74
myFloat_2=-46.08
- Sluit de Micro SD-kaart aan op de PC met een USB 3.0 SD-kaartlezer.
- Zorg ervoor dat de Micro SD-kaart is geformatteerd als FAT16 of FAT32 (u kunt online zoeken naar instructies).
- Plaats het config.txt-bestand in de hoofdmap van de Micro SD-kaart.
- Koppel de Micro SD-kaart veilig los van de PC.
- Verbind de Micro SD-kaart met de Arduino Nano via de Micro SD-kaartmodule, volgens het bedradingsschema.
- Kopieer onderstaande code en open deze met de Arduino IDE.
/*
* Deze Arduino Nano code is ontwikkeld door newbiely.nl
* Deze Arduino Nano code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-nano/arduino-nano-read-config-from-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 4
#define FILE_NAME "config.txt"
#define KEY_MAX_LENGTH 30 // change it if key is longer
#define VALUE_MAX_LENGTH 30 // change it if value is longer
// variables
int myInt_1;
int myInt_2;
float myFloat_1;
float myFloat_2;
String myString_1;
String myString_2;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD Card failed, or not present"));
while (1); // don't do anything more:
}
Serial.println(F("SD Card initialized."));
myInt_1 = SD_findInt(F("myInt_1"));
myInt_2 = SD_findInt(F("myInt_2"));
myFloat_1 = SD_findFloat(F("myFloat_1"));
myFloat_2 = SD_findFloat(F("myFloat_2"));
myString_1 = SD_findString(F("myString_1"));
myString_2 = SD_findString(F("myString_2"));
Serial.print(F("myInt_1 = "));
Serial.println(myInt_1);
Serial.print(F("myInt_2 = "));
Serial.println(myInt_2);
Serial.print(F("myFloat_1 = "));
Serial.println(myFloat_1);
Serial.print(F("myFloat_2 = "));
Serial.println(myFloat_2);
Serial.print(F("myString_1 = "));
Serial.println(myString_1);
Serial.print(F("myString_2 = "));
Serial.println(myString_2);
}
void loop() {
}
bool SD_available(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return value_length > 0;
}
int SD_findInt(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Int(value_string, value_length);
}
float SD_findFloat(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Float(value_string, value_length);
}
String SD_findString(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2String(value_string, value_length);
}
int SD_findKey(const __FlashStringHelper * key, char * value) {
File configFile = SD.open(FILE_NAME);
if (!configFile) {
Serial.print(F("SD Card: error on opening file "));
Serial.println(FILE_NAME);
return;
}
char key_string[KEY_MAX_LENGTH];
char SD_buffer[KEY_MAX_LENGTH + VALUE_MAX_LENGTH + 1]; // 1 is = character
int key_length = 0;
int value_length = 0;
// Flash string to string
PGM_P keyPoiter;
keyPoiter = reinterpret_cast<PGM_P>(key);
byte ch;
do {
ch = pgm_read_byte(keyPoiter++);
if (ch != 0)
key_string[key_length++] = ch;
} while (ch != 0);
// check line by line
while (configFile.available()) {
int buffer_length = configFile.readBytesUntil('\n', SD_buffer, 100);
if (SD_buffer[buffer_length - 1] == '\r')
buffer_length--; // trim the \r
if (buffer_length > (key_length + 1)) { // 1 is = character
if (memcmp(SD_buffer, key_string, key_length) == 0) { // equal
if (SD_buffer[key_length] == '=') {
value_length = buffer_length - key_length - 1;
memcpy(value, SD_buffer + key_length + 1, value_length);
break;
}
}
}
}
configFile.close(); // close the file
return value_length;
}
int HELPER_ascii2Int(char *ascii, int length) {
int sign = 1;
int number = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c >= '0' && c <= '9')
number = number * 10 + (c - '0');
}
}
return number * sign;
}
float HELPER_ascii2Float(char *ascii, int length) {
int sign = 1;
int decimalPlace = 0;
float number = 0;
float decimal = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c == '.')
decimalPlace = 1;
else if (c >= '0' && c <= '9') {
if (!decimalPlace)
number = number * 10 + (c - '0');
else {
decimal += ((float)(c - '0') / pow(10.0, decimalPlace));
decimalPlace++;
}
}
}
}
return (number + decimal) * sign;
}
String HELPER_ascii2String(char *ascii, int length) {
String str;
str.reserve(length);
str = "";
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
str += String(c);
}
return str;
}
- Klik op de Upload-knop in de Arduino IDE om de code te compileren en te uploaden naar de Arduino Nano.
- Controleer de Serial Monitor voor het resultaat.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
SD Card initialized.
myInt_1 = 2
myInt_2 = -105
myFloat_1 = 0.74
myFloat_2 = -46.08
myString_1 = Hello
myString_2 = ArduinoGetStarted.com
- De Serial Monitor toont de waarden van variabelen die overeenkomen met die op de Micro SD-kaart.
U kunt de code nu aanpassen om extra variabelen toe te voegen.
※ Notiz:
De code houdt geen rekening met de volgorde van key-value paren. Hij zoekt het bestand van begin tot eind totdat de key wordt gevonden.
Video Tutorial
We overwegen het maken van videotutorials. Als u videotutorials belangrijk vindt, abonneer u dan op ons YouTube-kanaal om ons te motiveren de video's te maken.
Functiereferenties
Gerelateerde Tutorials
📱 Aanbevolen apps
English for KidsSpelenderwijs Engels leren voor jonge kinderen.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Bubble NoteZelfverwijderende notities – schrijf ze als berichten.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Didn't BuyVersla impulsaankopen en bespaar meer.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Knowledge PathOefentoetsen om alles te leren.Ontdek het opGoogle PlayBeschikbaar in deApp Store