Arduino UNO R4 - LED - Knipperen Zonder Vertraging
Stel u voor dat de Arduino UNO R4 twee taken moet uitvoeren: een LED laten knipperen en detecteren wanneer een knop wordt ingedrukt. Als we de delay() functie gebruiken, kan de Arduino UNO R4 enkele knopindrukken missen. In deze tutorial leren we hoe we de Arduino UNO R4 een LED laten knipperen en een knop laten monitoren om ervoor te zorgen dat elke knopindruk wordt gedetecteerd.
We zullen hieronder drie voorbeelden doorlopen en hun verschillen vergelijken.
- Arduino UNO R4 laat een LED knipperen met de delay() functie.
- Arduino UNO R4 laat een LED knipperen met de millis() functie.
- Arduino UNO R4 laat een LED knipperen met de ezLED bibliotheek.
※ Notiz:
- Deze methode doet meer dan alleen LED laten knipperen en knopstatus controleren. Het stelt Arduino UNO R4 in staat om meerdere taken tegelijkertijd uit te voeren zonder onderbreking.
- Deze tutorial geeft gedetailleerde informatie om u te helpen begrijpen hoe het werkt. Voor eenvoud kunt u de Arduino UNO R4 - LED bibliotheek gebruiken.
Benodigde Hardware
Of u kunt de volgende kits kopen:
| 1 | × | DIYables STEM V4 IoT Starterskit (Arduino inbegrepen) | |
| 1 | × | DIYables Sensorkit (30 sensoren/displays) | |
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Bedradingsschema
This image is created using Fritzing. Click to enlarge image
Zie De beste manier om Arduino Uno R4 en andere componenten van stroom te voorzien.
Arduino UNO R4 Code - Met Vertraging
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-blink-led-without-delay
*/
#define LED_PIN 3 // The Arduino UNO R4 pin connected to the LED
#define BUTTON_PIN 7 // The Arduino UNO R4 pin connected to the button
#define BLINK_INTERVAL 1000 // interval at which to blink LED (milliseconds)
int led_state = LOW; // led_state used to set the LED
int prev_button_state = LOW; // will store last time button was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// if the LED is off turn it on and vice-versa
led_state = (led_state == LOW) ? HIGH : LOW;
// set the LED with the led_state of the variable
digitalWrite(LED_PIN, led_state);
delay(BLINK_INTERVAL); // If button is pressed during this time, Arduino CANNOT detect
int button_state = digitalRead(BUTTON_PIN);
if (button_state != prev_button_state) {
// print out the state of the button:
Serial.println(button_state);
// save the last state of button
prev_button_state = button_state;
}
// DO OTHER WORKS HERE
}
Snelle Stappen
Volg deze instructies stap voor stap:
- Als dit uw eerste keer is met de Arduino Uno R4 WiFi/Minima, raadpleeg dan de tutorial over het instellen van de omgeving voor Arduino Uno R4 WiFi/Minima in de Arduino IDE.
- Bedraad de componenten volgens het bijgeleverde schema.
- Sluit het Arduino Uno R4 bord aan op uw computer met een USB-kabel.
- Start de Arduino IDE op uw computer.
- Selecteer het juiste Arduino Uno R4 bord (bijv., Arduino Uno R4 WiFi) en COM-poort.
- Kopieer de meegeleverde code en plak deze in de Arduino IDE.
- Klik op de Upload knop in de Arduino IDE om de code over te zetten naar de Arduino UNO R4.
- Open de Seriële Monitor.
- Druk vier keer op de knop.
- Observeer de LED: Deze schakelt elke seconde aan en uit.
- Controleer de weergave op de Seriële Monitor.
COM6
1
0
Autoscroll
Clear output
9600 baud
Newline
- Enkele knopindrukken werden niet getoond op de Seriële Monitor omdat de Arduino UNO R4 geen taken kan uitvoeren tijdens een vertraging. Als gevolg hiervan mist het de detectie van die indrukken.
Arduino UNO R4 Code - Zonder Vertraging
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-blink-led-without-delay
*/
#define LED_PIN 3 // The Arduino UNO R4 pin connected to the LED
#define BUTTON_PIN 7 // The Arduino UNO R4 pin connected to the button
#define BLINK_INTERVAL 1000 // interval at which to blink LED (milliseconds)
int led_state = LOW; // led_state used to set the LED
int prev_button_state = LOW; // will store last time button was updated
unsigned long prev_millis = 0; // will store last time LED 1 was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
unsigned long current_millis = millis();
// check to see if it's time to blink the LED 1
if (current_millis - prev_millis >= BLINK_INTERVAL) {
// if the LED is off turn it on and vice-versa:
led_state = (led_state == LOW) ? HIGH : LOW;
// set the LED with the led_state of the variable:
digitalWrite(LED_PIN, led_state);
// save the last time you blinked the LED
prev_millis = current_millis;
}
// check button state's change
int button_state = digitalRead(BUTTON_PIN);
if (button_state != prev_button_state) {
// print out the state of the button:
Serial.println(button_state);
// save the last state of button
prev_button_state = button_state;
}
// DO OTHER WORKS HERE
}
Snelle Stappen
Volg deze instructies stap voor stap:
- Upload de meegeleverde code naar Arduino Uno R4
- Druk vier keer op de knop.
- Observeer de LED: Deze schakelt elke seconde tussen AAN en UIT.
- Controleer de uitvoer op de Seriële Monitor.
COM6
1
0
1
0
1
0
1
0
Autoscroll
Clear output
9600 baud
Newline
- Alle knopindrukken werden gedetecteerd.
Code Uitleg
De uitleg staat in het commentaargedeelte van de Arduino code hierboven.
Meer Taken Toevoegen
Deze code laat twee LED's knipperen op verschillende tijden en controleert ook of een knop wordt ingedrukt.
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-blink-led-without-delay
*/
#define LED_PIN_1 3 // The Arduino UNO R4 pin connected to the LED 1
#define LED_PIN_2 4 // The Arduino UNO R4 pin connected to the LED 2
#define BUTTON_PIN 7 // The Arduino UNO R4 pin connected to the button
#define BLINK_INTERVAL_1 1000 // interval at which to blink LED 1 (milliseconds)
#define BLINK_INTERVAL_2 500 // interval at which to blink LED 2 (milliseconds)
int led_state_1 = LOW; // led_state used to set the LED 1
int led_state_2 = LOW; // led_state used to set the LED 2
int prev_button_state = LOW; // will store last time button was updated
unsigned long prev_millis_1 = 0; // will store last time LED 1 was updated
unsigned long prev_millis_2 = 0; // will store last time LED 2 was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN_1, OUTPUT);
pinMode(LED_PIN_2, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
unsigned long current_millis = millis();
// check to see if it's time to blink the LED 1
if (current_millis - prev_millis_1 >= BLINK_INTERVAL_1) {
// if the LED is off turn it on and vice-versa:
led_state_1 = (led_state_1 == LOW) ? HIGH : LOW;
// set the LED with the led_state of the variable:
digitalWrite(LED_PIN_1, led_state_1);
// save the last time you blinked the LED
prev_millis_1 = current_millis;
}
// check to see if it's time to blink the LED 2
if (current_millis - prev_millis_2 >= BLINK_INTERVAL_2) {
// if the LED is off turn it on and vice-versa:
led_state_2 = (led_state_2 == LOW) ? HIGH : LOW;
// set the LED with the led_state of the variable:
digitalWrite(LED_PIN_2, led_state_2);
// save the last time you blinked the LED
prev_millis_2 = current_millis;
}
// check button state's change
int button_state = digitalRead(BUTTON_PIN);
if (button_state != prev_button_state) {
// print out the state of the button:
Serial.println(button_state);
// save the last state of button
prev_button_state = button_state;
}
// DO OTHER WORKS HERE
}
Video Tutorial
We overwegen het maken van videotutorials. Als u videotutorials belangrijk vindt, abonneer u dan op ons YouTube-kanaal om ons te motiveren de video's te maken.