Arduino UNO R4 - Joystick
In deze gids leren we hoe u een joystick met Arduino UNO R4 gebruikt. We behandelen:
- Hoe een joystick werkt
- Hoe u een joystick op Arduino UNO R4 aansluit
- Hoe u Arduino UNO R4 programmeert om waarden van een joystick te lezen
- Hoe u de waarden die van de joystick worden gelezen omzet in bruikbare waarden (bijv. XY-coördinaten of richtingen voor een motor)
Benodigde Hardware
Of u kunt de volgende kits kopen:
| 1 | × | DIYables STEM V4 IoT Starterskit (Arduino inbegrepen) | |
| 1 | × | DIYables STEM V4B IoT Starterskit (Arduino inbegrepen) | |
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Over de Joystick
U heeft misschien wel eens een joystick gezien die wordt gebruikt als game controller, speelgoed controller, of zelfs in grote machines zoals graafmachine controllers.
De joystick heeft twee potentiometers gerangschikt in een vierkante formatie en één drukknop. Deze geeft de volgende uitgangen:
- Een analoge waarde (van 0 tot 1023) voor de horizontale positie (X-coördinaat)
- Een analoge waarde (van 0 tot 1023) voor de verticale positie (Y-coördinaat)
- Een digitale status van een knop (HIGH of LOW)
Wanneer u twee analoge waarden combineert, vormen ze 2-D coördinaten. Deze coördinaten zijn gecentreerd wanneer de joystick niet wordt bewogen. U kunt gemakkelijk de werkelijke richting van deze coördinaten achterhalen door een testcode uit te voeren, wat we in het volgende gedeelte zullen behandelen.
Sommige toepassingen gebruiken mogelijk alle drie uitgangen, terwijl andere mogelijk slechts enkele ervan gebruiken.
Pinout
Een joystick gebruikt vijf pinnen.
- GND-pin: verbind met GND (0V)
- VCC-pin: verbind met VCC (5V)
- VRX-pin: geeft een analoge waarde voor de horizontale positie (X-coördinaat).
- VRY-pin: geeft een analoge waarde voor de verticale positie (Y-coördinaat).
- SW-pin: komt van de drukknop van de joystick. Deze is meestal open. Het gebruik van een pull-up weerstand maakt deze pin HIGH wanneer niet ingedrukt en LOW wanneer ingedrukt.
Hoe het Werkt
- Links/Rechts Beweging
- Wanneer u de joystick naar links of rechts beweegt, verandert dit het elektrische signaal (spanning) op de VRX-pin.
- Naar links bewegen verlaagt de spanning naar 0 volt.
- Naar rechts bewegen verhoogt de spanning naar 5 volt.
- De Arduino leest deze spanning en zet deze om naar een getal tussen 0 en 1023. Dus 0V komt overeen met 0, en 5V komt overeen met 1023.
- Omhoog/Omlaag Beweging:
- Op dezelfde manier verandert het bewegen van de joystick omhoog of omlaag de spanning op de VRY-pin.
- Omhoog bewegen verlaagt de spanning naar 0 volt.
- Omlaag bewegen verhoogt de spanning naar 5 volt.
- De Arduino leest deze spanning ook en zet deze om naar een getal tussen 0 en 1023, net als bij de VRX-pin.
- Gecombineerde Bewegingen:
- Wanneer u de joystick in elke richting beweegt (niet alleen puur links/rechts of omhoog/omlaag), verandert dit de spanning op zowel VRX- als VRY-pinnen gebaseerd op de positie langs elke as.
- De Joystick Indrukken:
- Wanneer u de joystick naar beneden drukt (zoals het indrukken van een knop), activeert dit een interne knop in de joystick.
- Als u een pull-up weerstand aansluit op de SW-pin, zal de spanning op deze pin veranderen van 5V naar 0V wanneer ingedrukt.
- De Arduino leest deze verandering als een digitaal signaal, dat HIGH (5V) toont wanneer niet ingedrukt en LOW (0V) wanneer ingedrukt.
Samenvattend: het bewegen van de joystick verandert spanningen op VRX en VRY, die de Arduino leest als getallen tussen 0 en 1023. Het indrukken van de joystick verandert de spanning op de SW-pin, die de Arduino leest als HIGH of LOW.
Bedradingsschema
Deze afbeelding is gemaakt met Fritzing. Klik om de afbeelding te vergroten.
Zie De beste manier om Arduino Uno R4 en andere componenten van stroom te voorzien.
Hoe Te Programmeren Voor Joystick
De joystick bestaat uit twee componenten: een analoog deel (X- en Y-as) en een digitaal deel (een drukknop).
- Om de waarden voor de X- en Y-assen te lezen, gebruikt u eenvoudig de functie analogRead() op de analoge ingangspin.
int xValue = analogRead(A1);
int yValue = analogRead(A0);
- Voor het digitale deel, wat een drukknop is: het is gewoon een knop. Een gemakkelijke en effectieve methode is het gebruik van de ezButton bibliotheek. Deze bibliotheek helpt de stabiliteit van de knop te beheren en activeert ook een intern systeem om de knop stabiel te houden. U kunt meer leren in de Arduino UNO R4 - Button tutorial. We zullen u laten zien hoe de code te gebruiken in het volgende deel van deze tutorial.
Na het verkrijgen van de waarden van analoge pinnen, moeten we ze mogelijk omzetten in beheersbare waarden. Het volgende gedeelte zal voorbeeldcodes hiervoor geven.
Arduino UNO R4 Code
Hier zijn voorbeeldcodes voor Arduino UNO R4:
- Voorbeeldcode: verkrijgt analoge waarden van joystick
- Voorbeeldcode: verkrijgt analoge waarden en controleert knopstatus op joystick
- Voorbeeldcode: zet analoge waarde om naar commando's: MOVE_LEFT, MOVE_RIGHT, MOVE_UP, MOVE_DOWN
- Voorbeeldcode: zet analoge waarden om naar hoeken om twee servomotoren te besturen (zoals in een pan-tilt camera)
Leest analoge waarden van joystick
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
int xValue = 0; // To store value of the X axis
int yValue = 0; // To store value of the Y axis
void setup() {
Serial.begin(9600) ;
}
void loop() {
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// print data to Serial Monitor on Arduino IDE
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.println(yValue);
delay(200);
}
Snelle Stappen
Volg deze instructies stap voor stap:
- Als dit uw eerste keer is met de Arduino Uno R4 WiFi/Minima, raadpleeg dan de tutorial over het instellen van de omgeving voor Arduino Uno R4 WiFi/Minima in de Arduino IDE.
- Sluit de joystick aan op Arduino UNO R4 volgens het bijgeleverde schema.
- Verbind het Arduino Uno R4 bord met uw computer via een USB-kabel.
- Start de Arduino IDE op uw computer.
- Selecteer het juiste Arduino Uno R4 bord (bijv. Arduino Uno R4 WiFi) en COM-poort.
- Kopieer de bovenstaande code en open deze in Arduino IDE
- Klik op de Upload knop in Arduino IDE om de code naar uw Arduino UNO R4 te uploaden
- Duw de joystick's duim helemaal naar de rand, draai deze vervolgens in een cirkel (klokgewijs of tegen de klok in)
- Controleer de resultaten op de Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
- Wanneer u de joystick draait, houd de Serial Monitor in de gaten. Als de X-waarde 0 toont, onthoud deze positie als links; het tegenovergestelde is rechts. Als de Y-waarde 0 is, noteer deze positie als omhoog; het tegenovergestelde is omlaag.
Leest analoge waarden en leest de knopstatus van een joystick
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#include <ezButton.h>
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
#define SW_PIN 2 // The Arduino UNO R4 pin connected to SW pin
ezButton button(SW_PIN);
int xValue = 0; // To store value of the X axis
int yValue = 0; // To store value of the Y axis
int bValue = 0; // To store value of the button
void setup() {
Serial.begin(9600) ;
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// Read the button value
bValue = button.getState();
if (button.isPressed()) {
Serial.println("The button is pressed");
// TODO do something here
}
if (button.isReleased()) {
Serial.println("The button is released");
// TODO do something here
}
// print data to Serial Monitor on Arduino IDE
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.print(yValue);
Serial.print(" : button = ");
Serial.println(bValue);
}
Snelle Stappen
- Ga naar het Libraries pictogram aan de linkerkant van de Arduino IDE.
- Zoek naar "ezButton" en vind de knop bibliotheek van ArduinoGetStarted.com
- Druk op de Install knop om de ezButton bibliotheek toe te voegen.
- Kopieer de code en open deze in Arduino IDE.
- Klik op de Upload knop in Arduino IDE om de code naar de Arduino UNO R4 te uploaden.
- Beweeg de joystick duim naar links, rechts, omhoog of omlaag.
- Druk naar beneden op de bovenkant van de joystick.
- Controleer de resultaten op de Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
Zet analoge waarde om naar MOVE LEFT/RIGHT/UP/DOWN commando's
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
int xValue = 0 ; // To store value of the X axis
int yValue = 0 ; // To store value of the Y axis
int command = COMMAND_NO;
void setup() {
Serial.begin(9600) ;
}
void loop() {
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (xValue < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (xValue > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (yValue < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (yValue > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
// TODO: add your task here
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
// TODO: add your task here
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
// TODO: add your task here
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
// TODO: add your task here
}
}
Snelle Stappen
- Kopieer de bovenstaande code en open deze met Arduino IDE.
- Klik op de Upload knop in Arduino IDE om de code naar Arduino UNO R4 te uploaden.
- Beweeg de joystick duim naar links, rechts, omhoog, omlaag of in een andere richting.
- Controleer de resultaten op de Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
※ Notiz:
Soms kan er geen commando zijn, één commando, of twee commando's tegelijkertijd (bijvoorbeeld UP en LEFT samen).
Zet analoge waarden om naar hoeken om twee servomotoren te besturen
U kunt informatie vinden in de Arduino UNO R4 - Joystick bestuurt Servo Motor tutorial.
Video Tutorial
We overwegen het maken van videotutorials. Als u videotutorials belangrijk vindt, abonneer u dan op ons YouTube-kanaal om ons te motiveren de video's te maken.
De onderstaande videodemo gebruikt de onderstaande code:
/*
* Deze Arduino UNO R4 code is ontwikkeld door newbiely.nl
* Deze Arduino UNO R4 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#include "Arduino_LED_Matrix.h"
// Pin definitions
#define PIN_VRX A1
#define PIN_VRY A0
#define PIN_SW 2
#define PIN_BUZZER 8
// Matrix display dimensions
#define MATRIX_WIDTH 12
#define MATRIX_HEIGHT 8
#define MAX_SNAKE_LENGTH 96
// Snake movement direction
enum Direction {
UP,
DOWN,
LEFT,
RIGHT
};
// Game state machine
enum GameState {
START_BOOT, // Initial boot screen scrolling "DIYables"
PLAYING, // Active gameplay
GAME_OVER // Game over score display
};
GameState currentState = START_BOOT;
ArduinoLEDMatrix matrix;
uint8_t frame[8][12];
// Snake properties
int snakeX[MAX_SNAKE_LENGTH];
int snakeY[MAX_SNAKE_LENGTH];
int snakeLength = 3;
int score = 0;
Direction dir = RIGHT;
Direction nextDir = RIGHT;
// Food coordinates
int foodX = 0;
int foodY = 0;
// Movement timing
unsigned long lastMoveTime = 0;
int moveInterval = 250;
// Text scrolling timing
int startTextX = 12;
int scoreTextX = 12;
unsigned long lastScrollTime = 0;
const int SCROLL_INTERVAL = 75;
// Physics particle structure for 3s fall effect
struct Particle {
float x;
float y;
float vx;
float vy;
bool active;
};
// Function prototypes
void resetGame();
void handleInput();
void updateGameLogic();
void renderGame();
void spawnFood();
void renderText(String text, int xOffset);
uint8_t getCharCol(char c, int col);
void playShootingStarEffect();
void playEatSound();
void playStartSound();
bool isButtonPressed();
void clearFrame();
void setup() {
pinMode(PIN_SW, INPUT_PULLUP);
pinMode(PIN_BUZZER, OUTPUT);
matrix.begin();
randomSeed(analogRead(A2));
}
void loop() {
switch (currentState) {
case START_BOOT:
// Show "DIYables" only on initial power-up
if (millis() - lastScrollTime >= SCROLL_INTERVAL) {
lastScrollTime = millis();
renderText("DIYables", startTextX);
startTextX--;
if (startTextX < -36) {
startTextX = 12;
}
}
if (isButtonPressed()) {
resetGame();
playStartSound();
currentState = PLAYING;
}
break;
case PLAYING:
handleInput();
updateGameLogic();
renderGame();
break;
case GAME_OVER:
// Display score ("Score: X")
if (millis() - lastScrollTime >= SCROLL_INTERVAL) {
lastScrollTime = millis();
String scoreStr = "Score: " + String(score);
renderText(scoreStr, scoreTextX);
scoreTextX--;
int strLen = scoreStr.length() * 4;
if (scoreTextX < -strLen) {
scoreTextX = 12;
}
}
// Press button to restart game directly
if (isButtonPressed()) {
resetGame();
playStartSound();
currentState = PLAYING;
}
break;
}
}
// Read Joystick axes independently for accurate 4-way directional control
void handleInput() {
int xVal = analogRead(PIN_VRX);
int yVal = analogRead(PIN_VRY);
int dx = xVal - 512;
int dy = yVal - 512;
// Prioritize axis with stronger deflection
if (abs(dx) > abs(dy)) {
if (dx < -200 && dir != RIGHT) nextDir = LEFT;
else if (dx > 200 && dir != LEFT) nextDir = RIGHT;
} else {
if (dy < -200 && dir != DOWN) nextDir = UP;
else if (dy > 200 && dir != UP) nextDir = DOWN;
}
}
// 3.0-second shooting star fall effect
void playShootingStarEffect() {
const int MAX_PARTICLES = 45;
Particle particles[MAX_PARTICLES];
int pCount = 0;
// Convert active LEDs (snake body and food) into free-falling particles
for (int r = 0; r < MATRIX_HEIGHT; r++) {
for (int c = 0; c < MATRIX_WIDTH; c++) {
if (frame[r][c] == 1 && pCount < 25) {
particles[pCount].x = c;
particles[pCount].y = r;
particles[pCount].vx = (float)random(-15, 15) / 100.0;
particles[pCount].vy = (float)random(-20, 5) / 100.0;
particles[pCount].active = true;
pCount++;
}
}
}
unsigned long startTime = millis();
unsigned long lastSpawn = 0;
// 3-second physics simulation loop
while (millis() - startTime < 3000) {
clearFrame();
unsigned long elapsedTime = millis() - startTime;
// Spawn additional falling star trails from top during the first 2.2 seconds
if (elapsedTime < 2200 && millis() - lastSpawn > 80 && pCount < MAX_PARTICLES) {
lastSpawn = millis();
particles[pCount].x = random(0, MATRIX_WIDTH);
particles[pCount].y = -random(1, 4);
particles[pCount].vx = (float)random(-5, 5) / 100.0;
particles[pCount].vy = (float)random(10, 30) / 100.0;
particles[pCount].active = true;
pCount++;
}
// Update particle positions
for (int i = 0; i < pCount; i++) {
if (!particles[i].active) continue;
particles[i].x += particles[i].vx;
particles[i].y += particles[i].vy;
particles[i].vy += 0.04; // Gravity acceleration
int px = (int)round(particles[i].x);
int py = (int)round(particles[i].y);
// Draw particle
if (py >= 0 && py < MATRIX_HEIGHT && px >= 0 && px < MATRIX_WIDTH) {
frame[py][px] = 1;
}
// Draw particle trail if falling rapidly
int tailY = py - 1;
if (tailY >= 0 && tailY < MATRIX_HEIGHT && px >= 0 && px < MATRIX_WIDTH && particles[i].vy > 0.3) {
frame[tailY][px] = 1;
}
// Deactivate particle once below screen
if (py >= MATRIX_HEIGHT + 3) {
particles[i].active = false;
}
}
matrix.renderBitmap(frame, 8, 12);
// Decreasing pitch sound from 1200Hz to 100Hz synchronized over 3 seconds
int soundFreq = 1200 - (int)((elapsedTime / 3000.0) * 1100);
if (soundFreq > 100) {
tone(PIN_BUZZER, soundFreq, 30);
}
delay(35);
}
noTone(PIN_BUZZER);
clearFrame();
matrix.renderBitmap(frame, 8, 12);
}
// 3x5 bitmap font data
uint8_t getCharCol(char c, int col) {
switch (c) {
// "DIYables" characters
case 'D': return (col==0)?0x1F:(col==1)?0x11:0x0E;
case 'I': return (col==0)?0x11:(col==1)?0x1F:0x11;
case 'Y': return (col==0)?0x03:(col==1)?0x1C:0x03;
case 'a': return (col==0)?0x0C:(col==1)?0x12:0x1E;
case 'b': return (col==0)?0x1F:(col==1)?0x14:0x08;
case 'l': return (col==0)?0x11:(col==1)?0x1F:0x10;
case 'e': return (col==0)?0x0C:(col==1)?0x16:0x14;
case 's': return (col==0)?0x14:(col==1)?0x16:0x0A;
// "Score:" characters
case 'S': return (col==0)?0x12:(col==1)?0x15:0x09;
case 'c': return (col==0)?0x0C:(col==1)?0x12:0x12;
case 'o': return (col==0)?0x0C:(col==1)?0x12:0x0C;
case 'r': return (col==0)?0x1E:(col==1)?0x04:0x02;
case ':': return (col==0)?0x00:(col==1)?0x0A:0x00;
case ' ': return 0x00;
// Digits 0 - 9
case '0': return (col==0)?0x0E:(col==1)?0x11:0x0E;
case '1': return (col==0)?0x12:(col==1)?0x1F:0x10;
case '2': return (col==0)?0x19:(col==1)?0x15:0x12;
case '3': return (col==0)?0x11:(col==1)?0x15:0x0A;
case '4': return (col==0)?0x07:(col==1)?0x04:0x1F;
case '5': return (col==0)?0x17:(col==1)?0x15:0x09;
case '6': return (col==0)?0x0E:(col==1)?0x15:0x09;
case '7': return (col==0)?0x19:(col==1)?0x05:0x03;
case '8': return (col==0)?0x0A:(col==1)?0x15:0x0A;
case '9': return (col==0)?0x12:(col==1)?0x15:0x0E;
default: return 0x00;
}
}
// Render string to LED matrix frame
void renderText(String text, int xOffset) {
clearFrame();
int curX = xOffset;
int topY = 1;
for (int i = 0; i < text.length(); i++) {
char ch = text.charAt(i);
for (int col = 0; col < 3; col++) {
int screenX = curX + col;
if (screenX >= 0 && screenX < MATRIX_WIDTH) {
uint8_t colData = getCharCol(ch, col);
for (int row = 0; row < 5; row++) {
if ((colData >> row) & 1) {
frame[topY + row][screenX] = 1;
}
}
}
}
curX += 4;
}
matrix.renderBitmap(frame, 8, 12);
}
// Snake game logic update
void updateGameLogic() {
if (millis() - lastMoveTime < moveInterval) return;
lastMoveTime = millis();
dir = nextDir;
int newHeadX = snakeX[0];
int newHeadY = snakeY[0];
switch (dir) {
case UP: newHeadY--; break;
case DOWN: newHeadY++; break;
case LEFT: newHeadX--; break;
case RIGHT: newHeadX++; break;
}
// Wall collision -> Game Over
if (newHeadX < 0 || newHeadX >= MATRIX_WIDTH || newHeadY < 0 || newHeadY >= MATRIX_HEIGHT) {
playShootingStarEffect();
scoreTextX = 12;
currentState = GAME_OVER;
return;
}
// Self-collision -> Game Over
for (int i = 0; i < snakeLength; i++) {
if (snakeX[i] == newHeadX && snakeY[i] == newHeadY) {
playShootingStarEffect();
scoreTextX = 12;
currentState = GAME_OVER;
return;
}
}
bool ateFood = (newHeadX == foodX && newHeadY == foodY);
if (ateFood) {
snakeLength++;
score++;
playEatSound();
if (moveInterval > 100) {
moveInterval -= 5;
}
}
for (int i = snakeLength - 1; i > 0; i--) {
snakeX[i] = snakeX[i - 1];
snakeY[i] = snakeY[i - 1];
}
snakeX[0] = newHeadX;
snakeY[0] = newHeadY;
if (ateFood) {
spawnFood();
}
}
void renderGame() {
clearFrame();
frame[foodY][foodX] = 1;
for (int i = 0; i < snakeLength; i++) {
frame[snakeY[i]][snakeX[i]] = 1;
}
matrix.renderBitmap(frame, 8, 12);
}
void spawnFood() {
bool onSnake;
do {
onSnake = false;
foodX = random(0, MATRIX_WIDTH);
foodY = random(0, MATRIX_HEIGHT);
for (int i = 0; i < snakeLength; i++) {
if (snakeX[i] == foodX && snakeY[i] == foodY) {
onSnake = true;
break;
}
}
} while (onSnake);
}
void resetGame() {
snakeLength = 3;
score = 0;
dir = RIGHT;
nextDir = RIGHT;
moveInterval = 250;
snakeX[0] = 4; snakeY[0] = 3;
snakeX[1] = 3; snakeY[1] = 3;
snakeX[2] = 2; snakeY[2] = 3;
spawnFood();
}
bool isButtonPressed() {
static bool lastState = HIGH;
bool state = digitalRead(PIN_SW);
if (lastState == HIGH && state == LOW) {
delay(50);
lastState = state;
return true;
}
lastState = state;
return false;
}
void clearFrame() {
memset(frame, 0, sizeof(frame));
}
void playEatSound() {
tone(PIN_BUZZER, 1200, 60);
}
void playStartSound() {
tone(PIN_BUZZER, 440, 80); delay(90);
tone(PIN_BUZZER, 554, 80); delay(90);
tone(PIN_BUZZER, 659, 120); delay(120);
}
Functie Referenties
Gerelateerde Tutorials
📱 Aanbevolen apps
English for KidsSpelenderwijs Engels leren voor jonge kinderen.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Bubble NoteZelfverwijderende notities – schrijf ze als berichten.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Didn't BuyVersla impulsaankopen en bespaar meer.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Knowledge PathOefentoetsen om alles te leren.Ontdek het opGoogle PlayBeschikbaar in deApp Store