ESP32 - Configuratie lezen vanaf SD-kaart
In deze tutorial duiken we in het gebruik van een configuratiebestand op een Micro SD-kaart. De tutorial behandelt de volgende aspecten:
- Een bestand config.txt opslaan op de Micro SD-kaart, met daarin key-value paren.
- De configuratie uitlezen vanaf de Micro SD-kaart en opslaan in een int variabele.
- De configuratie uitlezen vanaf de Micro SD-kaart en opslaan in een float variabele.
- De configuratie uitlezen vanaf de Micro SD-kaart en opslaan in een String variabele.
Deze tutorial stelt u in staat om configuratie-instellingen te beheren via een bestand op de Micro SD-kaart, waardoor flexibiliteit ontstaat voor verschillende datatypes zoals integers, floats en strings.
Hardware Benodigd
Of u kunt de volgende kits kopen:
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Over Micro SD-kaart Module
Bent u niet vertrouwd met de Micro SD-kaart Module, inclusief de pinout, functionaliteit en programmering? Leer er meer over in de ESP32 - Micro SD-kaart tutorial.
Hoe Het Werkt
De key-value paren staan vooraf opgeslagen op de Micro SD-kaart volgens het volgende formaat:
- Elke key-value paar staat op een aparte regel. Met andere woorden, elk key-value paar wordt gescheiden door een newline karakter.
- De key en value worden gescheiden door het = teken.
De ESP32-code zoekt naar de key, vindt de bijbehorende waarde en slaat deze waarde op in een variabele. Het type variabele kan int, float of String zijn.
Aansluitschema
Deze afbeelding is gemaakt met Fritzing. Klik om de afbeelding te vergroten.
※ Notiz:
Als u een Ethernet shield of een ander shield met een Micro SD-kaart houder gebruikt, hoeft u de Micro SD-kaart Module niet te gebruiken. U hoeft dan alleen de Micro SD-kaart in de houder op het shield te plaatsen.
Hoe Configuratie naar Variabelen te lezen
- Maak een config.txt bestand aan op uw PC via Kladblok (Notepad) of Notepad++
- Kopieer onderstaande key-value paren en plak deze in config.txt:
myString_1=Hello
myString_2=newbiely.com
myInt_1=2
myInt_2=-105
myFloat_1=0.74
myFloat_2=-46.08
- Verbind de Micro SD-kaart met de PC via de USB 3.0 SD-kaartlezer
- Zorg ervoor dat de Micro SD-kaart geformatteerd is als FAT16 of FAT32 (zoek online hoe dit te doen)
- Kopieer het config.txt bestand naar de root directory van de Micro SD-kaart
- Koppel de Micro SD-kaart los van de PC
- Verbind de Micro SD-kaart met de ESP32 via de Micro SD-kaart Module volgens het bovenstaande aansluitschema
- Kopieer onderstaande code en open deze in de Arduino IDE
/*
* Deze ESP32 code is ontwikkeld door newbiely.nl
* Deze ESP32 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/esp32/esp32-read-config-from-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 5 // The ESP32 pin GPIO5
#define FILE_NAME "/config.txt"
#define KEY_MAX_LENGTH 30 // change it if key is longer
#define VALUE_MAX_LENGTH 30 // change it if value is longer
// variables
int myInt_1;
int myInt_2;
float myFloat_1;
float myFloat_2;
String myString_1;
String myString_2;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
while (1) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
delay(1000);
}
}
Serial.println(F("SD Card initialized."));
myInt_1 = SD_findInt(F("myInt_1"));
myInt_2 = SD_findInt(F("myInt_2"));
myFloat_1 = SD_findFloat(F("myFloat_1"));
myFloat_2 = SD_findFloat(F("myFloat_2"));
myString_1 = SD_findString(F("myString_1"));
myString_2 = SD_findString(F("myString_2"));
Serial.print(F("myInt_1 = "));
Serial.println(myInt_1);
Serial.print(F("myInt_2 = "));
Serial.println(myInt_2);
Serial.print(F("myFloat_1 = "));
Serial.println(myFloat_1);
Serial.print(F("myFloat_2 = "));
Serial.println(myFloat_2);
Serial.print(F("myString_1 = "));
Serial.println(myString_1);
Serial.print(F("myString_2 = "));
Serial.println(myString_2);
}
void loop() {
}
bool SD_available(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return value_length > 0;
}
int SD_findInt(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Int(value_string, value_length);
}
float SD_findFloat(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Float(value_string, value_length);
}
String SD_findString(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2String(value_string, value_length);
}
int SD_findKey(const __FlashStringHelper * key, char * value) {
File configFile = SD.open(FILE_NAME);
if (!configFile) {
Serial.print(F("SD Card: Issue encountered while attempting to open the file "));
Serial.println(FILE_NAME);
return;
}
char key_string[KEY_MAX_LENGTH];
char SD_buffer[KEY_MAX_LENGTH + VALUE_MAX_LENGTH + 1]; // 1 is = character
int key_length = 0;
int value_length = 0;
// Flash string to string
PGM_P keyPoiter;
keyPoiter = reinterpret_cast<PGM_P>(key);
byte ch;
do {
ch = pgm_read_byte(keyPoiter++);
if (ch != 0)
key_string[key_length++] = ch;
} while (ch != 0);
// check line by line
while (configFile.available()) {
int buffer_length = configFile.readBytesUntil('\n', SD_buffer, 100);
if (SD_buffer[buffer_length - 1] == '\r')
buffer_length--; // trim the \r
if (buffer_length > (key_length + 1)) { // 1 is = character
if (memcmp(SD_buffer, key_string, key_length) == 0) { // equal
if (SD_buffer[key_length] == '=') {
value_length = buffer_length - key_length - 1;
memcpy(value, SD_buffer + key_length + 1, value_length);
break;
}
}
}
}
configFile.close(); // close the file
return value_length;
}
int HELPER_ascii2Int(char *ascii, int length) {
int sign = 1;
int number = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c >= '0' && c <= '9')
number = number * 10 + (c - '0');
}
}
return number * sign;
}
float HELPER_ascii2Float(char *ascii, int length) {
int sign = 1;
int decimalPlace = 0;
float number = 0;
float decimal = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c == '.')
decimalPlace = 1;
else if (c >= '0' && c <= '9') {
if (!decimalPlace)
number = number * 10 + (c - '0');
else {
decimal += ((float)(c - '0') / pow(10.0, decimalPlace));
decimalPlace++;
}
}
}
}
return (number + decimal) * sign;
}
String HELPER_ascii2String(char *ascii, int length) {
String str;
str.reserve(length);
str = "";
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
str += String(c);
}
return str;
}
- Klik op de Upload knop in Arduino IDE om de code naar de ESP32 te uploaden
- Bekijk het resultaat in de Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
SD Card initialized.
myInt_1 = 2
myInt_2 = -105
myFloat_1 = 0.74
myFloat_2 = -46.08
myString_1 = Hello
myString_2 = newbiely.com
- De Serial Monitor toont de waardes van de variabelen, die identiek zijn aan de waarden opgeslagen op de Micro SD-kaart
U kunt de code nu aanpassen om meer variabelen toe te voegen.
※ Notiz:
De bovenstaande code maakt zich geen zorgen over de volgorde van de key-value paren. Hij zoekt altijd van boven naar beneden door het bestand totdat hij de juiste key vindt.
Video Tutorial
We overwegen het maken van videotutorials. Als u videotutorials belangrijk vindt, abonneer u dan op ons YouTube-kanaal om ons te motiveren de video's te maken.
Functiereferenties
Gerelateerde Tutorials
📱 Aanbevolen apps
English for KidsSpelenderwijs Engels leren voor jonge kinderen.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Bubble NoteZelfverwijderende notities – schrijf ze als berichten.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Didn't BuyVersla impulsaankopen en bespaar meer.Ontdek het opGoogle PlayBeschikbaar in deApp Store
Knowledge PathOefentoetsen om alles te leren.Ontdek het opGoogle PlayBeschikbaar in deApp Store