ESP32 - Verkeerslicht
In deze handleiding gaan we ontdekken hoe u de ESP32 kunt gebruiken om een verkeerslichtmodule te besturen. We leren in detail:
- Hoe u de verkeerslichtmodule aansluit op een ESP32
- Hoe u de ESP32 programmeert om een RGB verkeerslichtmodule te besturen
- Hoe u de ESP32 programmeert om de RGB verkeerslichtmodule aan te sturen zonder gebruik te maken van de delay() functie
Hardware Benodigdheden
Of u kunt de volgende kits kopen:
| 1 | × | DIYables Sensorkit (30 sensoren/displays) | |
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Over de Verkeerslicht Module
Pinout
Een verkeerslichtmodule heeft 4 pinnen:
- GND pin: De aarde-pin, sluit deze pin aan op GND van de ESP32.
- R pin: De pin voor het aansturen van het rode licht, verbind deze pin met een digitale uitgang van de ESP32.
- Y pin: De pin voor het aansturen van het gele licht, verbind deze pin met een digitale uitgang van de ESP32.
- G pin: De pin voor het aansturen van het groene licht, verbind deze pin met een digitale uitgang van de ESP32.
Hoe Het Werkt
Aansluitschema
- Hoe u de ESP32 en het verkeerslicht aansluit met een breadboard (experimenteerprint)
This image is created using Fritzing. Click to enlarge image
- Hoe u de ESP32 en het verkeerslicht aansluit met een schroefklem breakout bord
Hoe Programma Voor Verkeerslicht Module te Schrijven
- Configureer de pinnen van de ESP32 als digitale uitgangen met de pinMode() functie
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
- Programma om het rode licht aan te zetten met de digitalWrite() functie:
digitalWrite(PIN_RED, HIGH); // zet Rood aan
digitalWrite(PIN_YELLOW, LOW); // zet Geel uit
digitalWrite(PIN_GREEN, LOW); // zet Groen uit
delay(RED_TIME); // houd het rode LED aan voor een bepaalde tijd
ESP32 Code
/*
* Deze ESP32 code is ontwikkeld door newbiely.nl
* Deze ESP32 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/esp32/esp32-traffic-light
*/
#define PIN_RED 25 // The ESP32 pin GPIO25 connected to R pin of traffic light module
#define PIN_YELLOW 26 // The ESP32 pin GPIO26 connected to Y pin of traffic light module
#define PIN_GREEN 27 // The ESP32 pin GPIO27 connected to G pin of traffic light module
#define RED_TIME 4000 // RED time in millisecond
#define YELLOW_TIME 4000 // YELLOW time in millisecond
#define GREEN_TIME 4000 // GREEN time in millisecond
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// the loop function runs over and over again forever
void loop() {
// red light on
digitalWrite(PIN_RED, HIGH); // turn on
digitalWrite(PIN_YELLOW, LOW); // turn off
digitalWrite(PIN_GREEN, LOW); // turn off
delay(RED_TIME); // keep red light on during a period of time
// yellow light on
digitalWrite(PIN_RED, LOW); // turn off
digitalWrite(PIN_YELLOW, HIGH); // turn on
digitalWrite(PIN_GREEN, LOW); // turn off
delay(YELLOW_TIME); // keep yellow light on during a period of time
// green light on
digitalWrite(PIN_RED, LOW); // turn off
digitalWrite(PIN_YELLOW, LOW); // turn off
digitalWrite(PIN_GREEN, HIGH); // turn on
delay(GREEN_TIME); // keep green light on during a period of time
}
Snelle Stappen
- Als u de ESP32 voor het eerst gebruikt, bekijk dan hoe u de ESP32 omgeving instelt in Arduino IDE.
- Maak de bedrading volgens de bovenstaande afbeelding.
- Verbind de ESP32 met uw pc via een micro USB-kabel.
- Open Arduino IDE op uw pc.
- Selecteer het juiste ESP32 board (bijv. ESP32 Dev Module) en de juiste COM-poort.
- Kopieer de bovenstaande code en open deze in Arduino IDE.
- Klik op de Upload knop in Arduino IDE om de code naar de ESP32 te uploaden.
- Controleer het verkeerslichtmodule op correct functioneren.
Het is belangrijk om te vermelden dat de precieze werking van een verkeerslicht kan variëren afhankelijk van het ontwerp en de technologie die in verschillende regio’s en kruispunten wordt gebruikt. De hierboven beschreven principes geven een algemeen begrip van hoe verkeerslichten het verkeer reguleren en de veiligheid op de weg verbeteren.
De bovenstaande code laat zien hoe elk licht afzonderlijk wordt bestuurd. Laten we de code nu verbeteren voor een betere optimalisatie.
ESP32 Code Optimalisatie
- Laten we de code verbeteren door een functie toe te voegen voor het aansturen van de lichten.
/*
* Deze ESP32 code is ontwikkeld door newbiely.nl
* Deze ESP32 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/esp32/esp32-traffic-light
*/
#define PIN_RED 25 // The ESP32 pin GPIO25 connected to R pin of traffic light module
#define PIN_YELLOW 26 // The ESP32 pin GPIO26 connected to Y pin of traffic light module
#define PIN_GREEN 27 // The ESP32 pin GPIO27 connected to G pin of traffic light module
#define RED_TIME 2000 // RED time in millisecond
#define YELLOW_TIME 1000 // YELLOW time in millisecond
#define GREEN_TIME 2000 // GREEN time in millisecond
#define RED 0 // Index in array
#define YELLOW 1 // Index in array
#define GREEN 2 // Index in array
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// the loop function runs over and over again forever
void loop() {
// red light on
trafic_light_on(RED);
delay(times[RED]); // keep red light on during a period of time
// yellow light on
trafic_light_on(YELLOW);
delay(times[YELLOW]); // keep yellow light on during a period of time
// green light on
trafic_light_on(GREEN);
delay(times[GREEN]); // keep green light on during a period of time
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // turn on
else
digitalWrite(pins[i], LOW); // turn off
}
}
- Laten we de code verbeteren door een for-loop te gebruiken.
/*
* Deze ESP32 code is ontwikkeld door newbiely.nl
* Deze ESP32 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/esp32/esp32-traffic-light
*/
#define PIN_RED 25 // The ESP32 pin GPIO25 connected to R pin of traffic light module
#define PIN_YELLOW 26 // The ESP32 pin GPIO26 connected to Y pin of traffic light module
#define PIN_GREEN 27 // The ESP32 pin GPIO27 connected to G pin of traffic light module
#define RED_TIME 2000 // RED time in millisecond
#define YELLOW_TIME 1000 // YELLOW time in millisecond
#define GREEN_TIME 2000 // GREEN time in millisecond
#define RED 0 // Index in array
#define YELLOW 1 // Index in array
#define GREEN 2 // Index in array
const int pins[] = {PIN_RED, PIN_YELLOW, PIN_GREEN};
const int times[] = {RED_TIME, YELLOW_TIME, GREEN_TIME};
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// the loop function runs over and over again forever
void loop() {
for (int light = RED; light <= GREEN; light ++) {
trafic_light_on(light);
delay(times[light]); // keep light on during a period of time
}
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i ++) {
if (i == light)
digitalWrite(pins[i], HIGH); // turn on
else
digitalWrite(pins[i], LOW); // turn off
}
}
- Laten we de code verbeteren door de millis() functie te gebruiken in plaats van delay().
/*
* Deze ESP32 code is ontwikkeld door newbiely.nl
* Deze ESP32 code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/esp32/esp32-traffic-light
*/
#define PIN_RED 25 // The ESP32 pin GPIO25 connected to R pin of traffic light module
#define PIN_YELLOW 26 // The ESP32 pin GPIO26 connected to Y pin of traffic light module
#define PIN_GREEN 27 // The ESP32 pin GPIO27 connected to G pin of traffic light module
#define RED_TIME 2000 // RED time in millisecond
#define YELLOW_TIME 1000 // YELLOW time in millisecond
#define GREEN_TIME 2000 // GREEN time in millisecond
#define RED 0 // Index in array
#define YELLOW 1 // Index in array
#define GREEN 2 // Index in array
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
unsigned long last_time = 0;
int light = RED; // start with RED light
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
trafic_light_on(light);
last_time = millis();
}
// the loop function runs over and over again forever
void loop() {
if ((millis() - last_time) > times[light]) {
light++;
if (light >= 3)
light = RED; // new circle
trafic_light_on(light);
last_time = millis();
}
// TO DO: your other code
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // turn on
else
digitalWrite(pins[i], LOW); // turn off
}
}
Video Tutorial
We overwegen het maken van videotutorials. Als u videotutorials belangrijk vindt, abonneer u dan op ons YouTube-kanaal om ons te motiveren de video's te maken.