Arduino Uno R4 WiFi bestuurt relais via web
In deze handleiding leert u hoe u een relais aanstuurt met een webinterface die toegankelijk is via een browser op een pc of smartphone. We gebruiken de Arduino Uno R4 WiFi, die geprogrammeerd wordt om als webserver te functioneren. Stel dat het IP-adres van de Arduino Uno R4 WiFi 192.168.0.2 is. Zo werkt het:
- Om toegang te krijgen tot de webinterface typt u eenvoudig 192.168.0.2 in de adresbalk van uw webbrowser. Dit stuurt een verzoek naar de Arduino, die als antwoord een webpagina terugstuurt met een aan/uit-knop om het relais te bedienen.
- Klikt u op de knop RELAY ON op de webpagina of voert u 192.168.0.2/relay1/on in de webbrowser in, dan activeert de Arduino het relais en stuurt een bijgewerkte webpagina terug.
- Klikt u op de knop RELAY OFF of voert u 192.168.0.2/relay1/off in, dan schakelt de Arduino het relais uit en ontvangt u opnieuw de bijgewerkte webpagina.
Door een relais aan te sluiten op apparaten zoals een solenoïde slot, gloeilamp, LED-strip, motor of actuator kunnen we deze via een webinterface bedienen.
Deze handleiding biedt een fundament dat u eenvoudig en creatief kunt aanpassen om het volgende te bereiken:
- Meerdere relais bedienen via een webinterface.
- De webgebruikersinterface (UI) naar eigen wens herontwerpen.
Hardware Vereist
Of u kunt de volgende kits kopen:
| 1 | × | DIYables Sensorkit (30 sensoren/displays) | |
| 1 | × | DIYables Sensorkit (18 sensoren/displays) |
Openbaarmaking: Sommige van de links in deze sectie zijn Amazon-affiliate links. We kunnen een commissie ontvangen voor aankopen die via deze links worden gedaan, zonder extra kosten voor u. We waarderen uw steun.
Over Relais en Arduino Uno R4
Als u nog niet bekend bent met Arduino Uno R4 en relais (pinout, werking, programmeren...), leer er dan meer over in de volgende handleidingen:
Aansluitschema
This image is created using Fritzing. Click to enlarge image
Arduino Code
/*
* Deze Arduino code is ontwikkeld door newbiely.nl
* Deze Arduino code wordt zonder enige beperking aan het publiek beschikbaar gesteld.
* Voor volledige instructies en schema's, bezoek:
* https://newbiely.nl/tutorials/arduino/arduino-uno-r4-wifi-controls-relay-via-web
*/
#include <UnoR4WiFi_WebServer.h>
// WiFi credentials
const char WIFI_SSID[] = "YOUR_WIFI_SSID";
const char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD";
#define RELAY_PIN 7 // Arduino pin connected to relay's pin
const char* HTML_CONTENT =
"<!DOCTYPE HTML>\n"
"<html>\n"
"<head>\n"
"<link rel=\"icon\" href=\"data:,\">\n"
"</head>\n"
"<body>\n"
"<a href=\"/relay1/on\">RELAY ON</a>\n"
"<br><br>\n"
"<a href=\"/relay1/off\">RELAY OFF</a>\n"
"</body>\n"
"</html>\n";
// Create web server instance
UnoR4WiFi_WebServer server;
// Page handlers
void handleHome(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
server.sendResponse(client, HTML_CONTENT);
}
void handleRelayOn(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
digitalWrite(RELAY_PIN, HIGH);
Serial.println("Turned relay ON");
server.sendResponse(client, HTML_CONTENT);
}
void handleRelayOff(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
digitalWrite(RELAY_PIN, LOW);
Serial.println("Turned relay OFF");
server.sendResponse(client, HTML_CONTENT);
}
void setup() {
Serial.begin(9600);
delay(1000);
// Initialize relay pin
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, LOW);
// Connect to WiFi
Serial.print("Connecting to ");
Serial.println(WIFI_SSID);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("connected!");
Serial.print("IP address: ");
Serial.println(WiFi.localIP());
// Configure routes
server.addRoute("/", handleHome);
server.addRoute("/relay1/on", handleRelayOn);
server.addRoute("/relay1/off", handleRelayOff);
// Start server
server.begin();
Serial.println("\n=== Web Server Ready! ===");
Serial.print("Visit: http://");
Serial.println(WiFi.localIP());
}
void loop() {
server.handleClient();
}
Snelle Stappen
- Als dit de eerste keer is dat u met de Arduino Uno R4 werkt, bekijk dan hoe u de omgeving instelt voor Arduino Uno R4 in de Arduino IDE.
- Open de Library Manager door te klikken op het icoon Library Manager aan de linkerkant van de Arduino IDE.
- Zoek op Web Server for Arduino Uno R4 WiFi en zoek de Web Server-bibliotheek gemaakt door DIYables.
- Klik op de knop Installeren om de Web Server-bibliotheek toe te voegen.
- Kopieer bovenstaande code en open deze met de Arduino IDE.
- Pas de wifi-gegevens (SSID en wachtwoord) in de code aan naar uw eigen netwerkgegevens.
- Klik op de knop Uploaden in de Arduino IDE om de code naar de Arduino te uploaden.
- Open de Seriële Monitor.
- Bekijk het resultaat in de Seriële Monitor.
COM6
Attempting to connect to SSID: YOUR_WIFI
IP Address: 192.168.0.2
signal strength (RSSI):-39 dBm
Autoscroll
Clear output
9600 baud
Newline
- U ziet dan een IP-adres, bijvoorbeeld: 192.168.0.2. Dit is het IP-adres van de Arduino Web Server.
- Open een webbrowser en voer één van de drie onderstaande formaten in de adresbalk in:
192.168.0.2
192.168.0.2/relay1/on
192.168.0.2/relay1/off
- Let op: het IP-adres kan anders zijn. Controleer altijd de actuele waarde in de Seriële Monitor.
- Verder ziet u de volgende uitvoer in de Seriële Monitor:
COM6
Connecting to YOUR_WIFI_SSID
connected!
IP address: 0.0.0.0
Starting web server on IP: 192.168.0.254
=== Web Server Ready! ===
Visit: http://192.168.0.254
Method: GET
Requested path: /
Client disconnected
Method: GET
Requested path: /relay1/on
Turned relay on
Client disconnected
Autoscroll
Clear output
9600 baud
Newline
- Controleer de status van het relais.
- U ziet de webpagina van de Arduino op de webbrowser zoals hieronder:
Nu kunt u de aan/uit-status van het relais via de webinterface bedienen. U kunt de code ook eenvoudig en creatief aanpassen om het volgende te realiseren:
- Meerdere relais bedienen via een webinterface.
- De webgebruikersinterface (UI) herontwerpen naar eigen wens.
Wilt u de webpagina visueel aantrekkelijker maken met een indrukwekkende grafische gebruikersinterface (UI), raadpleeg dan de Arduino - Web Server handleiding voor inspiratie en richtlijnen.